home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung / Power-Programmierung (Tewi)(1994).iso / magazine / nan_news / toolkit / netpv.prg < prev    next >
Text File  |  1991-08-15  |  3KB  |  91 lines
  1. /*
  2.  * File......: NETPV.PRG
  3.  * Author....: David Husnian
  4.  * Date......: $Date:   15 Aug 1991 23:04:06  $
  5.  * Revision..: $Revision:   1.2  $
  6.  * Log file..: $Logfile:   E:/nanfor/src/netpv.prv  $
  7.  * 
  8.  * This is an original work by David Husnian and is placed in the
  9.  * public domain.
  10.  *
  11.  * Modification history:
  12.  * ---------------------
  13.  *
  14.  * $Log:   E:/nanfor/src/netpv.prv  $
  15.  * 
  16.  *    Rev 1.2   15 Aug 1991 23:04:06   GLENN
  17.  * Forest Belt proofread/edited/cleaned up doc
  18.  * 
  19.  *    Rev 1.1   14 Jun 1991 19:52:30   GLENN
  20.  * Minor edit to file header
  21.  * 
  22.  *    Rev 1.0   01 Apr 1991 01:01:50   GLENN
  23.  * Nanforum Toolkit
  24.  *
  25.  */
  26.  
  27.  
  28. /*  $DOC$
  29.  *  $FUNCNAME$
  30.  *     FT_NETPV()
  31.  *  $CATEGORY$
  32.  *     Math
  33.  *  $ONELINER$
  34.  *     Calculate net present value
  35.  *  $SYNTAX$
  36.  *     FT_NETPV( <nInitialInvestment>, <nInterestRate>, <aCashFlow> ;
  37.  *               [, <nNoOfCashFlows> ] ) -> nNetPV
  38.  *  $ARGUMENTS$
  39.  *     <nInitialInvestment> is the amount of cash invested for purposes
  40.  *     of generating the cash flows.
  41.  *
  42.  *     <nInterestRate> is the annual interest rate used to discount
  43.  *     expected cash flows (10.5% = 10.5, not .105).
  44.  *
  45.  *     <aCashFlow> is an array of the expected cash receipts each year.
  46.  *
  47.  *     <nNoOfCashFlows> is the number of years cash flows are expected
  48.  *     (optional, Len( aCashFlow ) ).
  49.  *  $RETURNS$
  50.  *     The difference between the initial investment and the discounted
  51.  *     cash flow in dollars.
  52.  *  $DESCRIPTION$
  53.  *     This function calculates the net present value, the difference
  54.  *     between the cost of an initial investment and the present value
  55.  *     of the expected cash flow(s) from the investment.  The present
  56.  *     value of the expected cashflow(s) is calculated at the specified
  57.  *     interest rate, which is often referred to as the "cost of capital".
  58.  *
  59.  *     This function can be used to evaluate alternative investments.
  60.  *     The larger the NPV, the more profitable the investment.  See
  61.  *     also the FutureValue and PresentValue for further explanations.
  62.  *     The formula to calculate the net present value is:
  63.  *
  64.  *     NetPresentValue = SUM(CashFlow[i] / ((1 + InterestRate) ** i))
  65.  *                       FOR i = 1 TO NoOfCashFlows
  66.  *  $EXAMPLES$
  67.  *     nNetPresentValue := FT_NETPV(10000, 10, { 10000,15000,16000,17000 } )
  68.  *  $END$
  69.  */
  70.  
  71. #ifdef FT_TEST
  72.   FUNCTION MAIN()
  73.      ? FT_NETPV( 10000, 10, { 10000,15000,16000,17000 } )
  74.   RETURN ( nil )
  75. #endif
  76.  
  77.  
  78. FUNCTION FT_NETPV(nInitialInvestment, nInterestRate, aCashFlow, nNoOfCashFlows)
  79.  
  80.    LOCAL nNetPresentValue := 0
  81.  
  82.    nNoOfCashFlows := iif( nNoOfCashFlows == nil, len( aCashFlow ), nNoOfCashFlows )
  83.  
  84.    AEVAL(aCashFlow, ;
  85.          { | nElement, nElementNo | ;
  86.            nNetPresentValue += nElement / ;
  87.                                ((1 + (nInterestRate / 100)) ** nElementNo) }, ;
  88.          1, nNoOfCashFlows)
  89.  
  90.    RETURN (nNetPresentValue -= nInitialInvestment)
  91.